nix/home-manager/common/software/cli/nixvim.nix

{ inputs, pkgs, config, lib, theme, ... }: {
    imports = [
        inputs.nixvim.homeManagerModules.nixvim
    ] ++ lib.optional (builtins.isString theme) ../../../../stylix/${theme}/home-manager/nixvim.nix;

    programs.nixvim = {
        enable = true;
        viAlias = true;
        vimAlias = true;

        globals.mapleader = " ";
        globals.maplocalleader = " ";

        keymaps = let
            map = mode: key: action: { mode = mode; key = key; action = action; };
            nmap = key: action: map [ "n" ] key action;
            nvmap = key: action: map [ "n" "v" ] key action;
            imap = key: action: map [ "i" ] key action;
            desc = d: { options.desc = d; };
            silent = { options.silent = true; };
            expr = { options.expr = true; };
        in [
            # Unmap keys that aren't useful, or that we want to use for different things
            (nvmap "<Space>" "<Nop>" // silent)
            (nvmap "<Cr>" "<Nop>" // silent)
            (nvmap "s" "<Nop>" // silent)
            # Redo
            (nmap "R" "<C-r>")
            # Copy and paste
            (nvmap "<leader>y" "\"+y" // desc "Cop[y] to clipboard")
            (nvmap "<leader>p" "\"+p" // desc "[P]aste from clipboard")
            # Jump to start/end of line
            (nvmap "H" "0")
            (nvmap "L" "$")
            # Navigate up and down word wrapped text as if it were not word wrapped
            (nmap "k" "v:count == 0 ? 'gk' : 'k'" // silent // expr)
            (nmap "j" "v:count == 0 ? 'gj' : 'j'" // silent // expr)
            # Center cursor when jumping foward or back
            (nmap "<C-o>" "<C-o>zz")
            (nmap "<C-i>" "<C-i>zz")
        
            # Insert Mode

            # Normal Mode
            (nmap "<leader>ns" ":Neotree selector<C-r>"// desc "[S]elect neotree")
            (nmap "<leader>nt" ":Neotree toggle<C-r>" // desc "[T]oggle neotree")
            (nmap "<leader>nc" ":Neotree close<C-r>" // desc "[C]lose neotree")
            (nmap "<leader>nb" ":Neotree buffers<C-r>" // desc "Open [b]uffers")
        ];

        options = {
            number = true;
            shiftwidth = 2;
            # Indent wrapped text.
            breakindent = true;
            colorcolumn = "100";
            showmode = false;
        };
        plugins = {
            # Parser generator tool
            treesitter.enable = true;
            # Airline / Powerline alternative
            lualine.enable = true;
            # Snippet engine for neovim
            luasnip.enable = true;
            # Nix language syntax highlighting / file type associations
            nix.enable = true;
            # Run nix develop / shell without exiting vim 
            nix-develop.enable = true;
            # tab bar like Firefox or Chrome
            bufferline.enable = true;
            # Popup to show shortcuts
            which-key.enable = true;
            # Automatic indent
            intellitab.enable = true;
            #  Highlight all entries of the currently selected word
            illuminate.enable = true;
            # sidebar file browser
            nvim-tree.enable = true;
            # Gutter information for git modifications
            gitsigns.enable = true;
            # Terminal in vim
            toggleterm.enable = true;
            # Rainbow matching {} [] () 's
            rainbow-delimiters.enable = true;
            # Colorize hex colors inline
            nvim-colorizer.enable = true;

            telescope = {
                enable = true;
                extensions.fzf-native.enable = true;
                keymaps = {
                    "<leader><leader>" = {
                        action = "find_files";
                        desc = "Search files by name";
                    };
                    "<leader>s" = {
                        action = "live_grep";
                        desc = "Search by live grep";
                    };
                    "<leader>b" = {
                        action = "buffers";
                        desc = "Search open [B]uffers by file name";
                    };
                    "<leader>h" = {
                        action = "help_tags";
                        desc = "Search [H]elp";
                    };
                    "<leader>w" = {
                        action = "grep_string";
                        desc = "Search for [W]ord under cursor";
                    };
                    "<leader>g" = {
                        action = "buffers";
                        desc = "Search [G]it files";
                    };
                    "<leader>r" = {
                        action = "oldfiles";
                        desc = "Search [R]ecently opened files by name";
                    };
                };
            };

            lsp = {
                enable = true;
                servers = {
                    rust-analyzer = {
                        enable = true;
                        installCargo = true;
                        installRustc = true;
                    };
                    nixd.enable = true;
                    pylsp.enable = true;
                    html.enable = true;
                    cssls.enable = true;
                    bashls.enable = true;
                };
            };

            nvim-cmp = {
                enable = true;
                autoEnableSources = true;
                sources = [
                    { name = "nvim_lua"; }
                    { name = "nvim_lsp"; }
                    { name = "path";     }
                    { name = "buffer";   }
                ];
            };
        };

        colorschemes = {
            tokyonight.enable = true;
            gruvbox.enable = true;
            oxocarbon.enable = true;
            nord.enable = true;
            catppuccin.enable = true;
            kanagawa.enable = true;
            dracula.enable = true;
            
        };
        extraPlugins = with pkgs.vimPlugins; [
            everforest
        ];
    };
}