{
  description = "NixOS System Config";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-23.11";
    # nixpkgs-wayland - Wayland-specific packages not in nixpkgs
    nixpkgs-wayland.url = "github:nix-community/nixpkgs-wayland";
    # home-manager - Dotfile mnagement - add /master at the end to pull from master 
    home-manager.url = "github:nix-community/home-manager/release-23.11";
    home-manager.inputs.nixpkgs.follows = "nixpkgs";
    # lanzaboote - Secureboot Configuration
    lanzaboote.url = "github:nix-community/lanzaboote";
    lanzaboote.inputs.nixpkgs.follows = "nixpkgs";
    # nur - Nix User Repository - user-submitted / maintained packages
    nur.url = "github:nix-community/NUR";
    # sops-nix - Secret Management with SOPS using GPG Keys
    sops-nix.url = "github:Mic92/sops-nix";
    # doom-emacs - The Doom Emacs distribution`
    doom-emacs.url = "github:nix-community/nix-doom-emacs";
    # nixos-hardware - Hardware Configurations
    nixos-hardware.url = "github:NixOS/nixos-hardware/master";
    # nixos-generators - Automated Image / ISO Creation
    nixos-generators.url = "github:nix-community/nixos-generators";
    nixos-generators.inputs.nixpkgs.follows = "nixpkgs";
    # disko - Declarative Disk Partitioning
    disko.url = "github:nix-community/disko";
    disko.inputs.nixpkgs.follows = "nixpkgs";
    # Firefox theme, for "Gradience" GTK Theming
    firefox-gnome-theme.url = "github:rafaelmardojai/firefox-gnome-theme";
    firefox-gnome-theme.flake = false;
    # deploy-rs, declarative NixOS deployments
    deploy-rs.url = "github:serokell/deploy-rs";
    deploy-rs.inputs.nixpkgs.follows = "nixpkgs";
    # compose2nix - Convert docker-compose.yml files to nix syntax
    compose2nix.url = "github:aksiksi/compose2nix";
    compose2nix.inputs.nixpkgs.follows = "nixpkgs";
    # KDE Plasma 6 experimental flake
    kde2nix.url = "github:nix-community/kde2nix";
    # Manage Plasma desktop with Nix
    plasma-manager.url = "github:pjones/plasma-manager";
    plasma-manager.inputs.nixpkgs.follows = "nixpkgs";
    # Nix colorizer / themer 
    stylix.url = "github:danth/stylix";
    # Hyprland Flake
    hyprland.url = "github:hyprwm/Hyprland";
    # Hyprland Plugins
    hyprland-plugins.url = "github:hyprwm/hyprland-plugins";
    hyprland-plugins.inputs.hyprland.follows = "hyprland";
  };
  outputs = { self, nixpkgs, nixpkgs-wayland, home-manager, lanzaboote, nur, sops-nix, doom-emacs, nixos-generators, deploy-rs, ... } @inputs:
  let
    inherit (self) outputs;
    stateVersion = "23.11";
    hmStateVersion = "23.11";
    libx = import ./lib { inherit self inputs outputs stateVersion hmStateVersion; };
  in {
    nixosConfigurations = {
      osaka-linode-01  = libx.mkHost { hostname = "osaka-linode-01"; type = "small"; };
      framework-server = libx.mkHost { hostname = "framework-server"; };
      nuc-server       = libx.mkHost { hostname = "nuc-server"; };
      nixos-desktop    = libx.mkHost { hostname = "nixos-desktop"; desktop = "hyprland"; theme = "tokyo-night"; gpu = "nvidia"; };
      nixos-framework  = libx.mkHost { hostname = "nixos-framework"; desktop = "hyprland"; gpu = "amd";  theme = "green"; };
      backups-rpi4     = libx.mkHost { hostname = "backups-rpi4"; platform = "aarch64-linux"; type = "small"; };
      piaware-rpi4     = libx.mkHost { hostname = "piaware-rpi4"; platform = "aarch64-linux"; type = "small"; };
      quitman-rpi4     = libx.mkHost { hostname = "quitman-rpi4"; platform = "aarch64-linux"; type = "small"; };
    };
    homeConfigurations = {
      "albert@osaka-linode-01"  = libx.mkHome { hostname = "osaka-linode-01"; };
      "albert@framework-server" = libx.mkHome { hostname = "framework-server"; };
      "albert@nuc-server"       = libx.mkHome { hostname = "nuc-server"; };
      "albert@nixos-desktop"    = libx.mkHome { hostname = "nixos-desktop"; desktop = "hyprland"; theme = "tokyo-night"; };
      "albert@nixos-framework"  = libx.mkHome { hostname = "nixos-framework"; desktop = "hyprland"; theme = "green"; };
      "albert@backups-rpi4"     = libx.mkHome { hostname = "backups-rpi4"; platform = "aarch64-linux"; type = "small"; };
      "albert@piaware-rpi4"     = libx.mkHome { hostname = "piaware-rpi4"; platform = "aarch64-linux"; type = "small"; };
      "albert@quitman-rpi4"     = libx.mkHome { hostname = "quitman-rpi4"; platform = "aarch64-linux"; type = "small"; };
    };
    deploy.nodes = {
      osaka-linode-01  = libx.deploy { hostname = "osaka-linode-01"; };
      framework-server = libx.deploy { hostname = "framework-server"; };
    # nuc-server       = libx.deploy { hostname = "nuc-server"; };
    # nixos-desktop    = libx.deploy { hostname = "nixos-desktop"; };
    # nixos-framework  = libx.deploy { hostname = "nixos-framework"; };
      backups-rpi4     = libx.deploy { hostname = "backups-rpi4";  platform = "aarch64-linux"; };
      piaware-rpi4     = libx.deploy { hostname = "piaware-rpi4";  platform = "aarch64-linux"; };
    # quitman-rpi4     = libx.deploy { hostname = "quitman-rpi4";  platform = "aarch64-linux"; };
    };
    imageConfigurations = {
      nixos-linode-img  = libx.mkMinImage { hostname = "nixos-linode-img"; format = "linode"; };
      nixos-rpi4-img    = libx.mkImage    { hostname = "nixos-rpi4-img"; format = "sd-aarch64"; platform = "aarch64-linux"; };
      nixos-iso-console = libx.mkImage    { hostname = "nixos-iso-console"; format = "iso"; };
      nixos-iso-desktop = libx.mkImage    { hostname = "nixos-iso-desktop"; format = "iso"; desktop = "gnome"; };
    };

    # Checks for deploy-rs -  Makes deploy-rs fail when system evaluations fail
    checks = builtins.mapAttrs (system: deployLib: deployLib.deployChecks self.deploy) deploy-rs.lib;

    # Devshell for bootstrapping; acessible via 'nix develop'
    devShells = libx.forAllSystems (system:
      let pkgs = nixpkgs.legacyPackages.${system};
      in import ./shell.nix { inherit pkgs sops-nix deploy-rs system; }
    );
  };
}